Membuat Robot Emosi dari Kertas dengan Arduino

Skema & Diagram Sirkuit

Gambar Paper Emotions Bot

Hubungan komponen

• Arduino Nano 33 BLE Sense: Memproses sinyal audio Chirp menggunakan mikrofon internal.
• RGB LED: Menampilkan warna sesuai pesan emosi yang diterima.
• Maker Tape: Menghubungkan kaki RGB LED dengan pin Arduino tanpa menggunakan kabel dan solder.
• Kertas origami: Membentuk badan atau pelindung robot.

Pin yang digunakan

• GND: jalur bersama LED.
• D4: salah satu jalur kontrol LED.
• D7: salah satu jalur kontrol LED.
• D10: salah satu jalur kontrol LED.

Prinsip kerja: Perangkat pengirim mengirimkan pesan emosi melalui sinyal audio Chirp. Mikrofon pada Arduino Nano 33 BLE Sense menangkap sinyal tersebut. Chirp SDK memproses pesan yang diterima, kemudian program mengatur keluaran RGB LED sesuai jenis emosi.

Catatan teknis: Dokumentasi proyek menyebut RGB LED sebagai Common Anode, tetapi uraian penulis mengenai kaki bersama LED tidak sepenuhnya konsisten dengan istilah tersebut. Karena itu, periksa datasheet LED dan identifikasi kaki bersama sebelum membuat sambungan. Diagram skematik elektronik terpisah tidak ditampilkan pada dokumentasi yang diperiksa; gambar di atas merupakan gambar utama proyek.

Kode Program

/**-----------------------------------------------------------------------------

    Example code using the Chirp SDK to receive data using the
    Arduino Nano 33 Sense board.

    @file Nano33SenseReceive.ino

    @brief Create a developer account at https://developers.chirp.io,
    and copy and paste your key, secret and config string for the
    "16khz-mono-embedded" protocol into the credentials.h file.

    This example will start listening for chirps and print to the terminal
    when anything is received.

    *Note*: this example can be used in conjunction with the send example,
    to send and receive data in the same application.

    *Important*: The example will not start until this Serial Monitor is opened.
    To disable this behaviour, comment out the while(!Serial) line.

    Circuit:
      - Arduino Nano 33 BLE board

    Copyright © 2011-2019, Asio Ltd.
    All rights reserved.

  ----------------------------------------------------------------------------*/
#include <PDM.h>

#include "chirp_sdk.h"
#include "credentials.h"

#define SAMPLE_RATE       16000
#define BUFFER_SIZE       256

// Global variables
static chirp_sdk_t *chirp = NULL;
short sampleBuffer[BUFFER_SIZE];
volatile int samplesRead;

String red = String("Love");
String green = String("Happy");
String blue = String("Sad");

// Function definitions
void setupChirp(void);
void chirpErrorHandler(chirp_sdk_error_code_t code);
void onPDMdata(void);

void setup()
{
  Serial.begin(115200);

  pinMode(22, OUTPUT);
  pinMode(23, OUTPUT);
  pinMode(24, OUTPUT);

  digitalWrite(22, HIGH);
  digitalWrite(23, HIGH);
  digitalWrite(24, HIGH);

  // Enable high frequency oscillator
  NRF_CLOCK->EVENTS_HFCLKSTARTED = 0;
  NRF_CLOCK->TASKS_HFCLKSTART = 1;
  while (NRF_CLOCK->EVENTS_HFCLKSTARTED == 0);

  setupChirp();

  PDM.onReceive(onPDMdata);
  PDM.setGain(30);

  if (!PDM.begin(1, SAMPLE_RATE))
  {
    Serial.println("Failed to start PDM!");
    while (1);
  }
}

void loop()
{
  if (samplesRead)
  {
    chirp_sdk_error_code_t err = chirp_sdk_process_shorts_input(chirp, sampleBuffer, samplesRead);
    chirpErrorHandler(err);
    samplesRead = 0;
  }
}

void onPDMdata()
{
  int bytesAvailable = PDM.available();
  PDM.read(sampleBuffer, bytesAvailable);
  samplesRead = bytesAvailable / sizeof(short);
}

// Chirp callbacks
void onReceivingCallback(void *chirp, uint8_t *payload, size_t length, uint8_t channel)
{
  Serial.println("Receiving data...");
}

void onReceivedCallback(void *chirp, uint8_t *payload, size_t length, uint8_t channel)
{
  if (payload)
  {
    char *data = (char *)calloc(length + 1, sizeof(uint8_t));
    memcpy(data, payload, length * sizeof(uint8_t));
    Serial.print("Received data: ");
    Serial.println(data);

    if (data == red) {
      digitalWrite(22, LOW);
      digitalWrite(23, HIGH);
      digitalWrite(24, HIGH);
      digitalWrite(4, LOW);
      digitalWrite(7, LOW);
      digitalWrite(10, HIGH);
      delay(10000);
    } else if (data == green) {
      digitalWrite(22, HIGH);
      digitalWrite(23, LOW);
      digitalWrite(24, HIGH);
      digitalWrite(4, LOW);
      digitalWrite(7, HIGH);
      digitalWrite(10, LOW);
      delay(10000);
    } else if (data == blue) {
      digitalWrite(22, HIGH);
      digitalWrite(23, HIGH);
      digitalWrite(24, LOW);
      digitalWrite(4, HIGH);
      digitalWrite(7, LOW);
      digitalWrite(10, LOW);
      delay(10000);
    }

    free(data);
    delay(100);
    digitalWrite(4, HIGH);
    digitalWrite(7, HIGH);
    digitalWrite(10, HIGH);
  }
  else
  {
    Serial.println("Decode failed.");
  }
}

void chirpErrorHandler(chirp_sdk_error_code_t code)
{
  if (code != CHIRP_SDK_OK)
  {
    const char *errorString = chirp_sdk_error_code_to_string(code);
    Serial.println(errorString);
    exit(42);
  }
}

void setupChirp(void)
{
  chirp = new_chirp_sdk(CHIRP_APP_KEY, CHIRP_APP_SECRET);
  if (chirp == NULL)
  {
    Serial.println("Chirp initialisation failed.");
    return;
  }

  chirp_sdk_error_code_t err = chirp_sdk_set_config(chirp, CHIRP_APP_CONFIG);
  chirpErrorHandler(err);

  chirp_sdk_callback_set_t callback_set =
  {
    .on_state_changed = NULL,
    .on_sending = NULL,
    .on_sent = NULL,
    .on_receiving = onReceivingCallback,
    .on_received = onReceivedCallback
  };

  err = chirp_sdk_set_callbacks(chirp, callback_set);
  chirpErrorHandler(err);

  err = chirp_sdk_set_input_sample_rate(chirp, SAMPLE_RATE);
  chirpErrorHandler(err);

  // Correct the clock mismatch between requested and actual audio sample rate
  err = chirp_sdk_set_frequency_correction(chirp, 1.00812);
  chirpErrorHandler(err);

  err = chirp_sdk_start(chirp);
  chirpErrorHandler(err);

  Serial.println("Chirp SDK initialised.");
  Serial.flush();
}

Penjelasan kode:

• PDM.h: Mengakses mikrofon digital pada Arduino Nano 33 BLE Sense.
• chirp_sdk.h: Menghubungkan program dengan Chirp SDK.
• credentials.h: Menyimpan App Key, App Secret, dan konfigurasi Chirp.
• SAMPLE_RATE: Mengatur frekuensi sampel audio menjadi 16.000 Hz.
• onPDMdata(): Membaca data audio dari mikrofon.
• chirp_sdk_process_shorts_input(): Mengirim data audio ke Chirp SDK untuk diproses.
• onReceivedCallback(): Menangani pesan yang berhasil diterima dan mengatur warna LED.
• delay(10000): Mempertahankan tampilan warna selama 10 detik.
• setupChirp(): Menginisialisasi Chirp SDK dan mengatur callback penerimaan pesan.

Catatan kode: Kode di atas mengikuti sketch yang ditampilkan pada halaman Hackster. File credentials.h tidak disertakan dalam listing sehingga pengguna harus menyediakan konfigurasi Chirp sendiri. Kode sumber juga memiliki perbandingan data == red, data == green, dan data == blue antara pointer karakter dan objek String. Bagian tersebut perlu diperiksa atau disesuaikan agar perbandingan teks bekerja sesuai harapan pada lingkungan Arduino yang digunakan. Kode ini tidak dapat dijalankan tanpa library dan konfigurasi Chirp yang kompatibel.