Mengendalikan Rotasi Motor Servo dengan Arduino

Skema & Diagram Sirkuit

Foto Perakitan Servo

Diagram Perakitan Dasar

Diagram dengan Sumber Daya Terpisah

Diagram dengan Kapasitor

Skematik Sumber Daya Terpisah

Skematik Koneksi Dasar

Skematik dengan Kapasitor

Koneksi Utama

• Servo signal: pin digital 9 Arduino.
• Servo VCC: sumber tegangan sesuai spesifikasi motor.
• Servo GND: GND Arduino atau ground bersama.
• Kapasitor 470 µF: dipasang di antara VCC dan GND dengan memperhatikan polaritas.

Kode Program

/*
 * ElegooMotorServo-01.ino
 * A basic set of tests to drive a servo motor directly
 * 2018-10-12
 * armw
 * v0.1
 * © 2018 All Rights Reserved
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; either version 2 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
 * GNU General Public License for more details.
 *
 * Reference:
 * https://playground.arduino.cc/ComponentLib/Servo
 * https://www.arduino.cc/en/Reference/Servo
 *
 * Three use cases:
 * Use direct power from board to servo motor
 * Use 470 uF capacitor between VDC and GND
 * Use separate power supply with common ground
 */

#include <Servo.h> // Arduino Software Servo Library

#define PIN_SERVO 9
#define MAX_ANGLE 180
#define PULSEWIDTH_SG90_MAX 2000
#define PULSEWIDTH_SG90_MIN 1000
#define SG90_CENTER_ANGLE 90
#define SG90_CENTER_WIDTH 1500

Servo myServo;
int currentPosition = 90;

void centerServo()
{
  myServo.write(SG90_CENTER_ANGLE);
  myServo.writeMicroseconds(SG90_CENTER_WIDTH);
  currentPosition = myServo.read();
}

void setup()
{
  myServo.attach(PIN_SERVO, PULSEWIDTH_SG90_MIN, PULSEWIDTH_SG90_MAX);
  delay(100);
  centerServo();
  delay(100);
  myServo.detach();
  delay(100);
  myServo.attach(PIN_SERVO, PULSEWIDTH_SG90_MIN, PULSEWIDTH_SG90_MAX);
  delay(1000);
}

void panRightAngular()
{
  for (int i = 0; i <= MAX_ANGLE; i += 1)
  {
    myServo.write(i);
    delay(100);
    currentPosition = myServo.read();
  }
}

void panLeftAngular()
{
  for (int i = MAX_ANGLE; i >= 0; i -= 1)
  {
    myServo.write(i);
    delay(100);
    currentPosition = myServo.read();
  }
}

void panRightPulseWidth()
{
  for (int i = PULSEWIDTH_SG90_MIN; i <= PULSEWIDTH_SG90_MAX; i += 1)
  {
    myServo.writeMicroseconds(i);
    delay(5);
    currentPosition = myServo.read();
  }
}

void panLeftPulseWidth()
{
  for (int i = PULSEWIDTH_SG90_MAX; i >= PULSEWIDTH_SG90_MIN; i -= 1)
  {
    myServo.writeMicroseconds(i);
    delay(5);
    currentPosition = myServo.read();
  }
}

void loop()
{
  panRightAngular();
  delay(1000);
  centerServo();
  delay(1000);

  panLeftAngular();
  delay(1000);
  centerServo();
  delay(1000);

  panRightPulseWidth();
  delay(1000);
  centerServo();
  delay(1000);

  panLeftPulseWidth();
  delay(1000);
  centerServo();
  delay(1000);
}

Penjelasan Kode

• #include <Servo.h>: Memanggil Servo Library.
• PIN_SERVO 9: Menentukan pin digital 9 sebagai pin sinyal servo.
• MAX_ANGLE 180: Menetapkan sudut maksimum pengujian sebesar 180°.
• PULSEWIDTH_SG90_MIN 1000: Menentukan batas lebar pulsa minimum sebesar 1000 mikrodetik.
• PULSEWIDTH_SG90_MAX 2000: Menentukan batas lebar pulsa maksimum sebesar 2000 mikrodetik.
• SG90_CENTER_ANGLE 90: Menentukan posisi tengah servo berdasarkan sudut 90°.
• SG90_CENTER_WIDTH 1500: Menentukan lebar pulsa posisi tengah sebesar 1500 mikrodetik.
• myServo.attach(): Menghubungkan objek servo ke pin 9 dengan rentang lebar pulsa yang ditentukan.
• myServo.detach(): Melepaskan kendali sinyal servo dari library untuk sementara.
• myServo.write(): Mengatur posisi servo menggunakan nilai sudut dalam derajat.
• myServo.writeMicroseconds(): Mengatur posisi servo menggunakan nilai lebar pulsa dalam mikrodetik.
• myServo.read(): Membaca nilai sudut terakhir yang dikirimkan melalui fungsi write().
• centerServo(): Mengembalikan servo ke posisi tengah.
• panRightAngular(): Menggerakkan servo dari 0° hingga 180°.
• panLeftAngular(): Menggerakkan servo dari 180° hingga 0°.
• panRightPulseWidth(): Menaikkan lebar pulsa dari 1000 hingga 2000 mikrodetik.
• panLeftPulseWidth(): Menurunkan lebar pulsa dari 2000 hingga 1000 mikrodetik.

Bagaimana Program Bekerja?

Ketika Arduino dinyalakan, fungsi setup() menghubungkan servo ke pin 9 dan mengatur posisi awal ke tengah. Program kemudian menguji empat gerakan secara berurutan: bergerak dari 0° ke 180°, kembali ke 0°, bergerak berdasarkan peningkatan lebar pulsa, dan kembali berdasarkan penurunan lebar pulsa. Di antara setiap pengujian, servo dikembalikan ke posisi tengah dan diberi jeda satu detik.

Catatan teknis: Kode sumber pada halaman Hackster memiliki satu baris tanda pagar tunggal (#) setelah deklarasi library yang bukan sintaks C++ yang valid. Baris tersebut tidak disertakan dalam kode di atas agar program dapat dikompilasi. Logika pengujian servo dipertahankan. Kode sumber juga mendeklarasikan variabel currentPosition untuk menyimpan pembacaan sudut terakhir.

Informasi lisensi: Proyek sumber mencantumkan lisensi GPL 3+. Header lisensi dan atribusi pembuat kode tetap dicantumkan dalam dokumentasi ini.