Membuat Game Menembak Target dengan Arduino

Skema & Diagram Sirkuit

Diagram Rangkaian

Diagram rangkaian tersedia pada bagian Schematics di halaman proyek Hackster.io. Periksa diagram asli sebelum merakit karena koneksi rangkaian LDR menentukan apakah sensor terbaca HIGH atau LOW oleh program.

Kode Program

Program Arduino

Program menggunakan Arduino Nano untuk mengatur lima LED target, membaca lima LDR, mengelola skor dan kesempatan, serta menampilkan informasi pada LCD I2C.

#include <Wire.h>
#include <LiquidCrystal_I2C.h>

#define PIN_PIEZO 6

#define AMOUNT_SPACESHIPS 5
#define AMOUNT_SHOTS_INIT 5

#define MAX_SPACESHIP_DELAY 2000
#define MIN_SPACESHIP_DELAY 250
#define SPACESHIP_DELAY_STEP 100

#define TONE_SHOT 1
#define TONE_END_1 2
#define TONE_END_2 3

LiquidCrystal_I2C lcd(0x27, 16, 2);

bool gameRunning;
byte pinLEDs[AMOUNT_SPACESHIPS] = {9, 10, 11, 12, 13};
byte pinLDRs[AMOUNT_SPACESHIPS] = {2, 3, 4, 5, 7};
int activeSpaceship;
byte shots;
unsigned int spaceshipDelay;
unsigned int score;
unsigned long shipAppearance;

void setup() {
  Serial.begin(9600);

  lcd.begin();
  lcd.setCursor(1, 0);
  lcd.print(" Laser Shooter");
  lcd.setCursor(1, 1);
  lcd.print("    mircemk");

  randomSeed(analogRead(0));
  pinMode(PIN_PIEZO, OUTPUT);

  for (byte i = 0; i < AMOUNT_SPACESHIPS; i++) {
    pinMode(pinLEDs[i], OUTPUT);
    pinMode(pinLDRs[i], INPUT);
    digitalWrite(pinLEDs[i], LOW);
  }

  spaceshipDelay = MAX_SPACESHIP_DELAY;
  gameRunning = true;
  activeSpaceship = -1;
  score = 0;
  shots = AMOUNT_SHOTS_INIT;
  initAnimation();
}

void loop() {
  if (gameRunning) {
    updateSpaceships();
    checkShoot();
  }
}

void updateSpaceships() {
  if (activeSpaceship > -1) {
    if ((millis() - shipAppearance) > spaceshipDelay) {
      endGame();
    }
    return;
  }

  delay(random(500, 3000));

  activeSpaceship = random(0, AMOUNT_SPACESHIPS);
  digitalWrite(pinLEDs[activeSpaceship], HIGH);
  shipAppearance = millis();

  if (spaceshipDelay > (MIN_SPACESHIP_DELAY + SPACESHIP_DELAY_STEP)) {
    spaceshipDelay -= SPACESHIP_DELAY_STEP;
  }
}

void checkShoot() {
  if (activeSpaceship == -1) {
    return;
  }

  for (byte i = 0; i < AMOUNT_SPACESHIPS; i++) {
    if (digitalRead(pinLDRs[i]) == HIGH) {
      continue;
    }

    shots--;

    if (activeSpaceship == i) {
      digitalWrite(pinLEDs[activeSpaceship], LOW);
      activeSpaceship = -1;
      score++;
      shots++;
      tone(PIN_PIEZO, 400, 50);
      return;
    }

    if (shots <= 0) {
      endGame();
      return;
    }
  }
}

void initAnimation() {
  Serial.println("Incoming alien ships...");
  lcd.setCursor(1, 0);
  lcd.print("Incoming ships  ");
  lcd.setCursor(1, 1);
  lcd.print("  * * * * * *   ");

  for (byte i = 0; i < 9; i++) {
    for (byte j = 0; j < AMOUNT_SPACESHIPS; j++) {
      digitalWrite(pinLEDs[j], i % 2);
    }
    delay(250);
    tone(PIN_PIEZO, 1220 - (i % 2 * 50));
    delay(300);
    noTone(PIN_PIEZO);
  }
}

void endGame() {
  gameRunning = false;
  Serial.println("GAME OVER");

  lcd.setCursor(1, 0);
  lcd.print("  GAME OVER    ");
  lcd.setCursor(1, 1);
  lcd.print("Final score:");
  lcd.print(score);

  Serial.println("Final score: " + String(score));

  for (byte i = 0; i < 6; i++) {
    for (byte j = 0; j < AMOUNT_SPACESHIPS; j++) {
      digitalWrite(pinLEDs[j], i % 2);
    }
    tone(PIN_PIEZO, 660 - (i % 2 * 50));
    delay(300);
    noTone(PIN_PIEZO);
  }

  for (byte i = 0; i < AMOUNT_SPACESHIPS; i++) {
    digitalWrite(pinLEDs[i], LOW);
  }
}

Catatan Pemeriksaan Kode

• Konstanta TONE_SHOT, TONE_END_1, dan TONE_END_2 didefinisikan tetapi tidak digunakan dalam program.
• Push button tercantum pada daftar komponen, tetapi tidak digunakan dalam kode yang dipublikasikan.
• Program mengatur pin LDR sebagai INPUT dan membaca statusnya menggunakan digitalRead(). Karena itu, rangkaian LDR harus menghasilkan sinyal digital HIGH/LOW sesuai kondisi cahaya. Jangan langsung mengganti dengan pembacaan analog tanpa menyesuaikan logika program.
• Program memulai permainan secara otomatis saat board dinyalakan. Setelah GAME OVER, gameRunning menjadi false dan tidak ada mekanisme untuk memulai ulang tanpa reset board.
• Program menggunakan delay() saat menunggu target berikutnya sehingga pembacaan sensor juga tertunda selama jeda tersebut.
• Library LiquidCrystal_I2C memiliki beberapa variasi implementasi. Jika lcd.begin() tidak cocok dengan library yang dipasang, sesuaikan inisialisasi LCD dengan versi library yang digunakan.

Kode di atas mengikuti program yang dipublikasikan pada halaman sumber. Periksa kembali rangkaian dan kompatibilitas library sebelum digunakan.