Tug of War: Permainan Tarik Tambang dengan Arduino

Skema & Diagram Sirkuit

Diagram Rangkaian

Pemetaan Pin Berdasarkan Kode

• LED strip WS2812: pin digital 6.
• Tombol utama pemain 1: pin digital 2.
• Tombol utama pemain 2: pin digital 3.
• Buzzer: pin digital 4.
• Potensiometer pengatur kecerahan LED: pin analog A0.
• Potensiometer pengatur kecepatan: pin analog A1.
• Tombol BOOST pemain 1: pin digital 7.
• Tombol BOOST pemain 2: pin digital 8.

Keempat tombol menggunakan konfigurasi INPUT_PULLUP pada kode. Karena itu, tombol dibaca sebagai LOW ketika ditekan.

Catatan daya: Proyek menggunakan catu daya 5V dengan arus minimal 1A. LED strip WS2812 dapat membutuhkan arus yang cukup besar, terutama saat banyak LED menyala dengan kecerahan tinggi. Pastikan catu daya mampu memenuhi kebutuhan seluruh rangkaian dan hubungkan GND catu daya dengan GND Arduino. Periksa juga koneksi transistor dan resistor melalui diagram asli sebelum merakit.

Kode Program

#include <Adafruit_NeoPixel.h>

// Pin definitions
#define LED_PIN 6
#define BUTTON1_PIN 2
#define BUTTON2_PIN 3
#define BUZZER_PIN 4
#define LED_INTENSITY_POT A0
#define SPEED_POT A1
#define POWER1_PIN 7
#define POWER2_PIN 8

// LED strip configuration
#define NUM_LEDS 60
#define CENTER_POS 30

// Game constants
#define DEBOUNCE_TIME 50
#define VICTORY_FLASHES 3
#define FLASH_DELAY 200
#define MIN_CLICK_SPEED 1
#define MAX_CLICK_SPEED 5

// Power move constants
#define POWER_BOOST 3
#define POWER_MOVES_COUNT 3
#define POWER_FLASH_DURATION 500
#define MAX_POWER_SPEED (MAX_CLICK_SPEED + 2)

// Initialize LED strip
Adafruit_NeoPixel strip = Adafruit_NeoPixel(NUM_LEDS, LED_PIN, NEO_GRB + NEO_KHZ800);

// Colors
uint32_t COLOR_RED;
uint32_t COLOR_BLUE;
uint32_t COLOR_YELLOW;
uint32_t COLOR_MAGENTA;
const uint32_t COLOR_OFF = strip.Color(0, 0, 0);

// Game state variables
int flagPosition = CENTER_POS;
unsigned long lastButton1Press = 0;
unsigned long lastButton2Press = 0;
bool gameActive = false;
int clickSpeed = 1;

// Power move state variables
bool player1PowerActive = false;
bool player2PowerActive = false;
int player1PowerMovesLeft = 0;
int player2PowerMovesLeft = 0;
bool player1PowerAvailable = true;
bool player2PowerAvailable = true;
unsigned long lastPower1Press = 0;
unsigned long lastPower2Press = 0;

bool button1LastState = HIGH;
bool button2LastState = HIGH;
bool power1LastState = HIGH;
bool power2LastState = HIGH;

void setup() {
  strip.begin();
  strip.show();

  pinMode(BUTTON1_PIN, INPUT_PULLUP);
  pinMode(BUTTON2_PIN, INPUT_PULLUP);
  pinMode(POWER1_PIN, INPUT_PULLUP);
  pinMode(POWER2_PIN, INPUT_PULLUP);
  pinMode(BUZZER_PIN, OUTPUT);
  pinMode(LED_INTENSITY_POT, INPUT);
  pinMode(SPEED_POT, INPUT);

  button1LastState = digitalRead(BUTTON1_PIN);
  button2LastState = digitalRead(BUTTON2_PIN);
  power1LastState = digitalRead(POWER1_PIN);
  power2LastState = digitalRead(POWER2_PIN);

  resetGame();
}

void loop() {
  if (!gameActive) {
    playStartSequence();
  }

  if (gameActive) {
    updateColors();
    updateGameSpeed();
    checkPowerMoves();
    checkButtons();
    updateLEDs();
  }
}

void checkPowerMoves() {
  bool power1CurrentState = digitalRead(POWER1_PIN);
  bool power2CurrentState = digitalRead(POWER2_PIN);

  if (power1CurrentState == LOW && power1LastState == HIGH) {
    if (millis() - lastPower1Press > DEBOUNCE_TIME && player1PowerAvailable) {
      activatePowerMove(1);
      lastPower1Press = millis();
    }
  }

  if (power2CurrentState == LOW && power2LastState == HIGH) {
    if (millis() - lastPower2Press > DEBOUNCE_TIME && player2PowerAvailable) {
      activatePowerMove(2);
      lastPower2Press = millis();
    }
  }

  power1LastState = power1CurrentState;
  power2LastState = power2CurrentState;
}

void activatePowerMove(int player) {
  if (player == 1 && player1PowerAvailable) {
    player1PowerActive = true;
    player1PowerMovesLeft = POWER_MOVES_COUNT;
    player1PowerAvailable = false;
    flashPowerMove(1);
  } else if (player == 2 && player2PowerAvailable) {
    player2PowerActive = true;
    player2PowerMovesLeft = POWER_MOVES_COUNT;
    player2PowerAvailable = false;
    flashPowerMove(2);
  }
}

void flashPowerMove(int player) {
  strip.clear();
  if (player == 1) {
    for (int i = 0; i < CENTER_POS; i++) {
      strip.setPixelColor(i, COLOR_MAGENTA);
    }
    tone(BUZZER_PIN, 2000, 200);
  } else {
    for (int i = CENTER_POS; i < NUM_LEDS; i++) {
      strip.setPixelColor(i, COLOR_MAGENTA);
    }
    tone(BUZZER_PIN, 2500, 200);
  }
  strip.show();
  delay(POWER_FLASH_DURATION);
  updateLEDs();
}

void playStartSequence() {
  updateColors();

  for (int i = 0; i < 3; i++) {
    if (i < 2) {
      strip.clear();
      strip.setPixelColor(CENTER_POS, COLOR_RED);
      strip.setPixelColor(CENTER_POS - 1, COLOR_RED);
      strip.show();
      tone(BUZZER_PIN, 800, 200);
      delay(300);

      strip.clear();
      strip.show();
      delay(300);
    } else {
      strip.clear();
      strip.setPixelColor(CENTER_POS, COLOR_MAGENTA);
      strip.setPixelColor(CENTER_POS - 1, COLOR_MAGENTA);
      strip.show();
      tone(BUZZER_PIN, 1200, 400);
      delay(400);
    }
  }

  gameActive = true;
  flagPosition = CENTER_POS;
  updateLEDs();
}

void updateColors() {
  int intensity = map(analogRead(LED_INTENSITY_POT), 0, 1023, 0, 255);
  COLOR_RED = strip.Color(intensity, 0, 0);
  COLOR_BLUE = strip.Color(0, 0, intensity);
  COLOR_YELLOW = strip.Color(intensity, intensity, 0);
  COLOR_MAGENTA = strip.Color(intensity, 0, intensity);
}

void updateGameSpeed() {
  clickSpeed = map(analogRead(SPEED_POT), 0, 1023, MIN_CLICK_SPEED, MAX_CLICK_SPEED);
}

void checkButtons() {
  bool button1CurrentState = digitalRead(BUTTON1_PIN);
  bool button2CurrentState = digitalRead(BUTTON2_PIN);

  if (button1CurrentState == LOW && button1LastState == HIGH) {
    if (millis() - lastButton1Press > DEBOUNCE_TIME) {
      int moveAmount = clickSpeed;
      if (player1PowerActive && player1PowerMovesLeft > 0) {
        moveAmount = min(moveAmount + POWER_BOOST, MAX_POWER_SPEED);
        player1PowerMovesLeft--;
        if (player1PowerMovesLeft <= 0) {
          player1PowerActive = false;
        }
      }
      flagPosition -= moveAmount;
      tone(BUZZER_PIN, player1PowerActive ? 800 : 1000, 20);
      lastButton1Press = millis();
    }
  }

  if (button2CurrentState == LOW && button2LastState == HIGH) {
    if (millis() - lastButton2Press > DEBOUNCE_TIME) {
      int moveAmount = clickSpeed;
      if (player2PowerActive && player2PowerMovesLeft > 0) {
        moveAmount = min(moveAmount + POWER_BOOST, MAX_POWER_SPEED);
        player2PowerMovesLeft--;
        if (player2PowerMovesLeft <= 0) {
          player2PowerActive = false;
        }
      }
      flagPosition += moveAmount;
      tone(BUZZER_PIN, player2PowerActive ? 1300 : 1500, 20);
      lastButton2Press = millis();
    }
  }

  button1LastState = button1CurrentState;
  button2LastState = button2CurrentState;

  flagPosition = constrain(flagPosition, 1, NUM_LEDS - 2);
  if (flagPosition <= 1 || flagPosition >= NUM_LEDS - 2) {
    gameActive = false;
    celebrateVictory();
  }
}

void updateLEDs() {
  strip.clear();
  strip.setPixelColor(flagPosition, COLOR_RED);
  strip.setPixelColor(flagPosition - 1, COLOR_RED);

  for (int i = 0; i < flagPosition - 1; i++) {
    strip.setPixelColor(i, i == 0 ? COLOR_MAGENTA : COLOR_BLUE);
  }

  for (int i = flagPosition + 1; i < NUM_LEDS; i++) {
    strip.setPixelColor(i, i == NUM_LEDS - 1 ? COLOR_MAGENTA : COLOR_YELLOW);
  }

  strip.show();
}

void celebrateVictory() {
  uint32_t winnerColor = (flagPosition <= 1) ? COLOR_BLUE : COLOR_YELLOW;

  if (flagPosition <= 1) {
    playVictoryTune(1000);
  } else {
    playVictoryTune(1500);
  }

  for (int i = 0; i < VICTORY_FLASHES; i++) {
    for (int j = 0; j < NUM_LEDS; j++) {
      strip.setPixelColor(j, winnerColor);
    }
    strip.show();
    delay(FLASH_DELAY);

    strip.clear();
    strip.show();
    delay(FLASH_DELAY);
  }

  delay(3000);
  resetGame();
}

void playVictoryTune(int baseFreq) {
  tone(BUZZER_PIN, baseFreq, 200);
  delay(200);
  tone(BUZZER_PIN, baseFreq * 1.25, 200);
  delay(200);
  tone(BUZZER_PIN, baseFreq * 1.5, 400);
  delay(400);
}

void resetGame() {
  flagPosition = CENTER_POS;
  gameActive = false;
  player1PowerActive = false;
  player2PowerActive = false;
  player1PowerMovesLeft = 0;
  player2PowerMovesLeft = 0;
  player1PowerAvailable = true;
  player2PowerAvailable = true;
  updateLEDs();
}