Papan Skor Basket Pintar Berbasis Arduino dan Android

Skema & Diagram Sirkuit

Skema Rangkaian Smart Basketball Scoreboard

Proyek ini memiliki dua versi rangkaian Arduino. Versi pertama menggunakan Arduino Mega 2560 dan Bluetooth Shield, sedangkan versi kedua menggunakan Arduino Nano R3 dan modul HC-05. Penjelasan berikut berfokus pada konfigurasi pin program Arduino versi kedua yang dipublikasikan oleh pembuat.

Konfigurasi Pin Arduino Nano R3 Versi 2.0.0

• D2: Input digital dari E18-D80NK Infrared Proximity Sensor.
• D3: Input digital dari Grove Vibration Sensor SW-420.
• D4: Output PWM untuk kanal merah RGB LED.
• D5: Output PWM untuk kanal hijau RGB LED.
• D6: Output PWM untuk kanal biru RGB LED.
• D7: Jalur data sensor DHT22.
• D10: RX SoftwareSerial untuk menerima data dari TX HC-05.
• D11: TX SoftwareSerial untuk mengirim data menuju RX HC-05.
• GND: Ground bersama untuk Arduino dan perangkat elektronik.
• VCC: Catu daya modul dan sensor sesuai dengan spesifikasi tegangan masing-masing perangkat.

Penjelasan Alur Koneksi

Sensor E18-D80NK dihubungkan ke pin input digital D2. Program membaca kondisi LOW untuk mengenali deteksi objek. Sensor SW-420 dihubungkan ke D3 dan menghasilkan sinyal HIGH ketika getaran terdeteksi.

RGB LED menggunakan tiga jalur output yang dikendalikan secara terpisah. Kanal merah dihubungkan ke D4, kanal hijau ke D5, dan kanal biru ke D6. Gunakan resistor pembatas arus yang sesuai dan perhatikan konfigurasi common anode atau common cathode LED.

Sensor DHT22 dihubungkan melalui pin data D7. Pin VCC dan GND sensor harus terhubung ke sumber daya yang sesuai. Perhatikan kebutuhan pull-up resistor pada jalur data apabila modul DHT22 yang digunakan tidak memilikinya.

Modul HC-05 menggunakan komunikasi serial melalui SoftwareSerial. Pin RX Arduino pada konfigurasi SoftwareSerial adalah D10 dan terhubung ke TX HC-05. Pin TX Arduino adalah D11 dan terhubung ke RX HC-05. Perhatikan bahwa RX HC-05 bekerja pada level logika sekitar 3,3V. Gunakan voltage divider atau level shifter pada jalur TX Arduino menuju RX HC-05 apabila diperlukan.

Seluruh komponen harus menggunakan ground bersama agar sinyal dapat dibaca dengan stabil. Baterai 9V digunakan sebagai sumber daya pada rancangan proyek. Pastikan tegangan yang diberikan ke setiap komponen sesuai dengan spesifikasinya dan jangan menghubungkan baterai 9V secara langsung ke pin VCC sensor yang hanya mendukung tegangan lebih rendah.

Diagram Skematik Versi 1.1.0

Diagram Skematik Versi 2.0.0

Catatan: Nomor pin di atas mengacu pada definisi program Arduino versi 2.0.0. Dokumentasi yang berhasil dibaca tidak memberikan rincian eksplisit seluruh jalur VCC, GND, dan koneksi resistor dalam bentuk teks. Gunakan gambar skematik asli sebagai acuan akhir sebelum merakit rangkaian.

Kode Program

Kode Program Arduino Versi 2.0.0

Program berikut merupakan kode Arduino versi kedua yang dipublikasikan pada dokumentasi proyek. Program membutuhkan library DHT dan SoftwareSerial.

//----------------------------------------------------------------------------//
// Filename    : Scoreboard.ino
// Description : Smart Basketball Scoreboard
// Version     : 2.0.0
// Author      : Marcelo Avila de Oliveira
//----------------------------------------------------------------------------//

//----------------------------------------------------------------------------//
// LIBRARIES
//----------------------------------------------------------------------------//

#include "DHT.h"
#include "SoftwareSerial.h"

//----------------------------------------------------------------------------//
// DEFINITIONS
//----------------------------------------------------------------------------//

// #define DEBUG
// #define DEBUG_BLUE
// #define DEBUG_PROX
// #define DEBUG_VIBR
// #define DEBUG_DHT

#define DHTPIN 7
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

// BLUETOOTH MODULE (RX, TX)
SoftwareSerial Bluetooth(10, 11);

//----------------------------------------------------------------------------//
// CONSTANTS
//----------------------------------------------------------------------------//

const int prox_pin = 2;
const int vibr_pin = 3;
const int led_r_pin = 4;
const int led_g_pin = 5;
const int led_b_pin = 6;

const unsigned long wait_interval = 2000;
const unsigned long dht_interval = 10000;

const float percent_to_bright_factor = 100 * log10(2) / log10(255);

//----------------------------------------------------------------------------//
// VARIABLES
//----------------------------------------------------------------------------//

unsigned long wait_time;
unsigned long dht_time;

float humi, temp, heat;

boolean prox = false;
boolean vibr = false;
boolean wait = false;

//----------------------------------------------------------------------------//
// FUNCTIONS (SETTINGS)
//----------------------------------------------------------------------------//

void setup() {
    pinMode(prox_pin, INPUT);
    pinMode(vibr_pin, INPUT);
    pinMode(led_r_pin, OUTPUT);
    pinMode(led_g_pin, OUTPUT);
    pinMode(led_b_pin, OUTPUT);

    set_led(5, 100);

    Serial.begin(9600);
    setup_bluetooth();

    dht.begin();

    set_led(4, 100);

    #ifdef DEBUG
        Serial.println("Board is alive");
        Serial.println();
    #endif
}

void setup_bluetooth() {
    #ifdef DEBUG_BLUE
        Serial.println("Setting Bluetooth");
        Serial.println();
    #endif

    Bluetooth.begin(9600);

    while (Bluetooth.available()) {
        delay(50);
        Bluetooth.read();
    }
}

//----------------------------------------------------------------------------//
// FUNCTIONS (LIGHT)
//----------------------------------------------------------------------------//

int percent_to_bright(int percent) {
    return 256 - pow(2, percent / percent_to_bright_factor);
}

void set_led(int color, int bright) {
    // COLOR:
    // 0 = GREEN
    // 1 = YELLOW
    // 2 = RED
    // 3 = CYAN
    // 4 = BLUE
    // 5 = MAGENTA
    // 6 = WHITE

    if (color < 0 || color > 6 || bright < 0 || bright > 100) {
        return;
    }

    int led_r_bright = 255;
    int led_g_bright = 255;
    int led_b_bright = 255;
    int bright_aux = percent_to_bright(bright);

    switch (color) {
        case 0:
            led_g_bright = bright_aux;
            break;
        case 1:
            led_r_bright = bright_aux;
            led_g_bright = bright_aux;
            break;
        case 2:
            led_r_bright = bright_aux;
            break;
        case 3:
            led_g_bright = bright_aux;
            led_b_bright = bright_aux;
            break;
        case 4:
            led_b_bright = bright_aux;
            break;
        case 5:
            led_r_bright = bright_aux;
            led_b_bright = bright_aux;
            break;
        case 6:
            led_r_bright = bright_aux;
            led_g_bright = bright_aux;
            led_b_bright = bright_aux;
            break;
    }

    analogWrite(led_r_pin, led_r_bright);
    analogWrite(led_g_pin, led_g_bright);
    analogWrite(led_b_pin, led_b_bright);

    return;
}

//----------------------------------------------------------------------------//
// FUNCTIONS (CHECK)
//----------------------------------------------------------------------------//

void check_prox() {
    if (!prox) {
        if (digitalRead(prox_pin) == LOW) {
            #ifdef DEBUG_PROX
                Serial.println("Proximity detected");
                Serial.println();
            #endif

            set_led(0, 100);
            send_data(2);
            prox = true;

            if (!vibr) {
                wait = true;
                wait_time = millis() + wait_interval;
            }
        }
    }
}

void check_vibr() {
    if (!prox && !vibr) {
        if (digitalRead(vibr_pin) == HIGH) {
            #ifdef DEBUG_VIBR
                Serial.println("Vibration detected");
                Serial.println();
            #endif

            set_led(1, 100);

            vibr = true;
            wait = true;
            wait_time = millis() + wait_interval;
        }
    }
}

void check_wait() {
    if (wait && millis() > wait_time) {
        if (!prox) {
            set_led(2, 100);
            send_data(1);
        }

        reset();
    }
}

void check_dht() {
    if (!prox && !vibr) {
        if (millis() > dht_time) {
            humi = dht.readHumidity();
            temp = dht.readTemperature();
            heat = dht.computeHeatIndex(temp, humi, false);

            #ifdef DEBUG_DHT
                Serial.print("Humidity   : ");
                Serial.print(humi);
                Serial.println("%");
                Serial.print("Temperature: ");
                Serial.print(temp);
                Serial.println("C");
                Serial.print("Head Index : ");
                Serial.print(heat);
                Serial.println("C");
                Serial.println("");
            #endif

            send_data(0);
            dht_time = millis() + dht_interval;
        }
    }
}

//----------------------------------------------------------------------------//
// FUNCTIONS (MIS)
//----------------------------------------------------------------------------//

void send_data(int shot) {
    // SHOT:
    // 0 = NO DATA
    // 1 = WRONG SHOT (MISS)
    // 2 = RIGHT SHOT (SCORE)

    Bluetooth.print(humi);
    Bluetooth.print(temp);
    Bluetooth.print(heat);
    Bluetooth.print(shot);

    #ifdef DEBUG_BLUE
        Serial.println("Bluetooth sent");
        Serial.println();
    #endif
}

void reset() {
    vibr = false;
    prox = false;
    wait = false;

    delay(1000);

    set_led(4, 100);
}

//----------------------------------------------------------------------------//
// MAIN
//----------------------------------------------------------------------------//

void loop() {
    check_prox();
    check_vibr();
    check_wait();
    check_dht();
}

Catatan Kode dan Versi Program

Dokumentasi Hackster juga menyediakan Arduino code versi 1.1.0. Pada versi tersebut digunakan Serial1 untuk komunikasi Bluetooth, dengan konfigurasi pin sensor proximity D2, vibration D3, dan RGB LED D4, D5, D6. Interval waktu tunggu versi pertama adalah 3000 milidetik. Versi kedua menggunakan interval 2000 milidetik dan menambahkan pembacaan DHT22.

Kode Android versi 1.1.0 dan 2.0.0 ditampilkan sebagai berkas unduhan MIT App Inventor dan tidak tersedia sebagai pratinjau kode teks pada halaman dokumentasi. Oleh sebab itu, blok program Android tidak dapat direproduksi secara lengkap dari tampilan halaman tersebut.

Catatan teknis: Pada kode versi 2.0.0, fungsi send_data() mengirimkan nilai kelembapan, suhu, heat index, dan status tembakan secara berurutan tanpa pemisah eksplisit. Format komunikasi ini perlu diperhatikan ketika membuat parser data pada aplikasi Android.